Sed is a largely outdated, but still useful for processing very large files like logs and mailboxes
in pipes. The ability to be used as a
stage of the pipe is probably the most valuable feature of sed. Functionality is mainly limited to processing
the file in a uniform fashion performing the same operation on each line or selected region of the file.
Beyond that you probably need to switch to Perl...
Historically sed was based on regex paradigm that made Unix famous (and it was one of the tools that
demonstrated the power of regular expressions). Unfortunately like many other classic Unix tools it did not yet adopted Perl
compatible regular expression.
It's fair to state that SED is oriented mainly on those users who want to process large output fiules or logs and extract
some lines from them.
In all versions that I encounter diagnostic is really horrible (with infamous response
"command garbed" for all kind of mistakes in a pretty complex command set). Such response might be probably
appropriate for an environment when a Unix server has 32K of memory but not now ;-).
It is SED's ability to filter text in a pipeline
which distinguishes it from other types of editors
GNU version of sed (3.02) is an incremental improvement and can be recommended instead of vendor
supplied versions in most cases. It corrects several deficiencies of a typical "proprietary Unix" sed
implementations: GNU sed issues an exit code of 0 if the program terminated normally, 1 if there were
errors in the script, and 2 if there were errors during script execution. GNU sed v3.02.80 also
supports 0 in range addressing, which means that the range "0,/RE/" will match every line from the top
of the file to the first line containing /RE/, inclusive, and if /RE/ occurs on the first line of the
file, only line 1 will be matched.
GNU Sed 4.1.5 has a strange and annoying bug: even if the file was not changed it changes the timestamp
of the file.
GNU Sed 4.1.5 has a strange and annoying bug: even if the file was
not changed it changes the timestamp of the file.
See sed FAQ, version 014 for
detail of idiosyncrasies of various version and some helpful tips.
Sed's command set is antiquated, and it's usability and power can be easily improved (see, for example,
Custom sed Proposal by Simon Taylor). Please be aware that many symbols need to be escaped in order to get command
work. For example:
/\(string\)*/ # matches zero or more instances of 'string'
/\(string\)\+ / # matches one or more instances of 'string'
echo "abc3232" | sed -n "/\([0-9]\)2\(\1\)/p"
If you are not using sed in pipes IMHO the motivation to use it all is much less and I would go with
other tools if possible :-).
For complex transformations Perl is a better tool (see s2p -- sed to Perl translator).
For files that can be loaded in memory (for example Unix config files) ed is a better tool.
If you have to delete the fourth line from the file then you have to substitute
N=4
.
$ sed '4d' testfile.txt
Delete
Line from File
How to Delete First and Last Line from a File
You can delete the first line from a file using the same syntax as described in the previous example. You have to put
N=1
which
will remove the first line.
$ sed '1d' testfile.txt
To delete the last line from a file using the below command with
($)
sign
that denotes the last line of a file.
$ sed '$d' testfile.txt
Delete
First and Last Lines from File
How to Delete Range of Lines from a File
You can delete a range of lines from a file. Let's say you want to delete lines from 3 to 5, you can use the below syntax.
M
– starting line number
N
– Ending line number
$ sed 'M,Nd' testfile.txt
To actually delete, use the following command to do it.
$ sed '3,5d' testfile.txt
Delete
Range of Lines from-File
You can use
!
symbol
to negate the delete operation. This will delete all lines except the given range(3-5).
$ sed '3,5!d' testfile.txt
Negate
Operation
How to Blank Lines from a File
To delete all blank lines from a file run the following command. An important point to note is using this command, empty lines with
spaces will not be deleted. I have added empty lines and empty lines with spaces in my test file.
$ cat testfile.txt
First line
second line
Third line
Fourth line
Fifth line
Sixth line
SIXTH LINE
$ sed '/^$/d' testfile.txt
Lines
with Spaces Not Removed
From the above image, you can see empty lines are deleted but lines that have spaces are not deleted. To delete all lines including
spaces you can run the following command.
$ sed '/^[[:space:]]*$/d' testfile.txt
Lines
with Spaces Removed
How to Delete Lines Starting with Words in a File
To delete a line that starts with a certain word run the following command with
^
symbol
represents the start of the word followed by the actual word.
$ sed '/^First/d' testfile.txt
To delete a line that ends with a certain word run the following command. The word to be deleted followed by the
$
symbol
will delete lines.
$ sed '/LINE$/d' testfile.txt
Delete
Line Start with Words in File
How to Make Changes Directly into a File
To make the changes directly in the file using
sed
you
have to pass
-i
flag
which will make the changes directly in the file.
$ sed -i '/^[[:space:]]*$/d' testfile.txt
We have come to the end of the article. The
sed
command
will play a major part when you are working on manipulating any files. When combined with other Linux utilities like
awk
,
grep
you
can do more things with
sed
.
20 Sed (Stream Editor) Command Examples for Linux Users
by Pradeep Kumar · Published November 9, 2017 · Updated
November 9, 2017
Sed command or Stream Editor is very powerful utility offered by Linux/Unix
systems. It is mainly used for text substitution , find & replace but it can also perform other text manipulations like insertion
deletion search etc. With SED, we can edit complete files without actually having to open it. Sed also supports the use of regular
expressions, which makes sed an even more powerful test manipulation tool
In this article, we will learn to use SED command with the help some examples. Basic syntax for using sed command is,
sed OPTIONS [SCRIPT] [INPUTFILE ]
Now let's see some examples.
Example :1) Displaying partial text of a file
With sed, we can view only some part of a file rather than seeing whole file. To see some lines of the file, use the following
command,
[linuxtechi@localhost ~]$ sed -n 22,29p testfile.txt
here, option 'n' suppresses printing of whole file & option 'p' will print only line lines from 22 to 29.
Example :2) Display all except some lines
To display all content of a file except for some portion, use the following command,
[linuxtechi@localhost ~]$ sed 22,29d testfile.txt
Option 'd' will remove the mentioned lines from output.
Example :3) Display every 3rd line starting with Nth line
Do display content of every 3rd line starting with line number 2 or any other line, use the following command
[linuxtechi@localhost ~]$ sed -n '2-3p' file.txt
Example :4 ) Deleting a line using sed command
To delete a line with sed from a file, use the following command,
[linuxtechi@localhost ~]$ sed Nd testfile.txt
where 'N' is the line number & option 'd' will delete the mentioned line number. To delete the last line of the file, use
[linuxtechi@localhost ~]$ sed $d testfile.txt
Example :5) Deleting a range of lines
To delete a range of lines from the file, run
[linuxtechi@localhost ~]$ sed '29-34d' testfile.txt
This will delete lines 29 to 34 from testfile.txt file.
Example :6) Deleting lines other than the mentioned
To delete lines other than the mentioned lines from a file, we will use '!'
[linuxtechi@localhost ~]$ sed '29-34!d' testfile.txt
here '!' option is used as not, so it will reverse the condition i.e. will not delete the lines mentioned. All the lines other
29-34 will be deleted from the files testfile.txt.
Example :7) Adding Blank lines/spaces
To add a blank line after every non-blank line, we will use option 'G',
[linuxtechi@localhost ~]$ sed G testfile.txt
Example :8) Search and Replacing a string using sed
To search & replace a string from the file, we will use the following example,
[linuxtechi@localhost ~]$ sed 's/danger/safety/' testfile.txt
here option 's' will search for word 'danger' & replace it with 'safety' on every line for the first occurrence only.
Example :9) Search and replace a string from whole file using sed
To replace the word completely from the file, we will use option 'g' with 's',
[linuxtechi@localhost ~]$ sed 's/danger/safety/g' testfile.txt
Example :10) Replace the nth occurrence of string pattern
We can also substitute a string on nth occurrence from a file. Like replace 'danger' with 'safety' only on second occurrence,
[linuxtechi@localhost ~]$ sed 's/danger/safety/2' testfile.txt
To replace 'danger' on 2nd occurrence of every line from whole file, use
[linuxtechi@localhost ~]$ sed 's/danger/safety/2g' testfile.txt
Example :11) Replace a string on a particular line
To replace a string only from a particular line, use
[linuxtechi@localhost ~]$ sed '4 s/danger/safety/' testfile.txt
This will only substitute the string from 4th line of the file. We can also mention a range of lines instead of a single line,
[linuxtechi@localhost ~]$ sed '4-9 s/danger/safety/' testfile.txt
Example :12) Add a line after/before the matched search
To add a new line with some content after every pattern match, use option 'a' ,
[linuxtechi@localhost ~]$ sed '/danger/a "This is new line with text after match"' testfile.txt
To add a new line with some content a before every pattern match, use option 'i',
[linuxtechi@localhost ~]$ sed '/danger/i "This is new line with text before match" ' testfile.txt
Example :13) Change a whole line with matched pattern
To change a whole line to a new line when a search pattern matches we need to use option 'c' with sed,
[linuxtechi@localhost ~]$ sed '/danger/c "This will be the new line" ' testfile.txt
So when the pattern matches 'danger', whole line will be changed to the mentioned line.
Advanced options with sed
Up until now we were only using simple expressions with sed, now we will discuss some advanced uses of sed with regex,
Example :14) Running multiple sed commands
If we need to perform multiple sed expressions, we can use option 'e' to chain the sed commands,
[linuxtechi@localhost ~]$ sed -e 's/danger/safety/g' -e 's/hate/love/' testfile.txt
Example :15) Making a backup copy before editing a file
To create a backup copy of a file before we edit it, use option '-i.bak',
[linuxtechi@localhost ~]$ sed -i.bak -e 's/danger/safety/g' testfile.txt
This will create a backup copy of the file with extension .bak. You can also use other extension if you like.
Example :16) Delete a file line starting with & ending with a pattern
To delete a file line starting with a particular string & ending with another string, use
[linuxtechi@localhost ~]$ sed -e 's/danger.*stops//g' testfile.txt
This will delete the line with 'danger' on start & 'stops' in the end & it can have any number of words in between , '.*' defines
that part.
Example :17) Appending lines
To add some content before every line with sed & regex, use
[linuxtechi@localhost ~]$ sed -e 's/.*/testing sed &/' testfile.txt
So now every line will have 'testing sed' before it.
Example :18) Removing all commented lines & empty lines
To remove all commented lines i.e. lines with # & all the empty lines, use
[linuxtechi@localhost ~]$ sed -e 's/#.*//;/^$/d' testfile.txt
To only remove commented lines, use
[linuxtechi@localhost ~]$ sed -e 's/#.*//' testfile.txt
Example :19) Get list of all usernames from /etc/passwd
To get the list of all usernames from /etc/passwd file, use
[linuxtechi@localhost ~]$ sed 's/\([^:]*\).*/\1/' /etc/passwd
a complete list all usernames will be generated on screen as output.
Example :20) Prevent overwriting of system links with sed command
'sed -i' command has been know to remove system links & create only regular files in place of the link file. So to avoid such
a situation & prevent ' sed -i ' from destroying the links, use ' –follow-symklinks ' options with the command being executed.
Let's assume i want to disable SELinux on CentOS or RHEL Severs
[linuxtechi@localhost ~]# sed -i --follow-symlinks 's/SELINUX=enforcing/SELINUX=disabled/g' /etc/sysconfig/selinux
These were some examples to show sed, we can use these reference to employ them as & when needed. If you guys have any queries
related to this or any article, do share with us.
You are allowed to print copies of this tutorial for your personal use, and link to this page, but you are not allowed to
make electronic copies, or redistribute this tutorial in any form without permission.
Original version written in 1994 and published in the Sun Observer
Nice quote that reminds that in many cases AWK is a better tool then sed. If you know Perl, on current
computers it is as fast as sed.
6.2. How does sed compare with awk, perl,
and other utilities?
Awk is a much richer language with many features
of a programming language, including variable names, math functions, arrays, system calls, etc.
Its command structure is similar to sed:
address { command(s) }
which means that for each line or range of lines that matches the
address, execute the command(s). In both sed and awk, an address can be a line number or a RE somewhere
on the line, or both.
In program size, awk is 3-10 times larger than sed. Awk has most
of the functions of sed, but not all. Notably, sed supports backreferences (\1, \2, ...) to previous
expressions, and awk does not have any comparable syntax. (One exception: GNU awk v3.0 introduced
gensub(), which supports backreferences only on substitutions.)
Perl is a general-purpose programming language, with many features
beyond text processing and interprocess communication, taking it well past awk or other scripting
languages. Perl supports every feature sed does and has its own set of extended regular expressions,
which give it extensive power in pattern matching and processing. (Note: the standard perl distribution
comes with 's2p', a sed-to-perl conversion script. See
section
3.6 for more info.) Like sed and awk, perl scripts do not need to be compiled into binary code.
Like sed, perl can also run many useful "one-liners" from the command line, though with greater
flexibility; see question 4.41 ("How do I make substitutions in every file in a directory, or in
a complete directory tree?").
On the other hand, the current version of perl is from 8 to 35 times
larger than sed in its executables alone (perl's library modules and allied files not included!).
Further, for most simple tasks such as substitution, sed executes more quickly than either perl
or awk. All these utilities serve to process input text, transforming it to meet our needs . . .
or our arbitrary whims.
A sample application of sed(1) would be to delete the first 10 lines
of stdin and echo the rest to stdout:
sed -e '1,10d'
The -e
tells sed to execute the next command line argument as sed program. Since sed programs
often contain regular expressions, they will often contain characters that your shell interprets,
so you should get used to put all sed programs in single quotes so your shell won't interpret the
sed program. In this case, nothing bad would have happened, but since almost all other examples
will contain meta-characters, you really should get used to quoting your programs. This simple sed
program contains a pattern (``1,10'') and an action (``d''). What sed(1) does is apply all actions
whose pattern match and finally print the line unless the action was ``d''. If you don't want sed(1)
to print each line by default, you can give sed the -n
option. Then only lines that you print explicitly (with the ``p'' action) appear on stdout.
If we wanted to print only the first ten lines, we would have deleted
all the lines starting with 11:
sed -e '11,$d'
Note that $
is the last line. Because sed(1) processes the input line by line, it does not keep the whole input
in memory. This makes sed(1) very useful for processing large files, but it has it's drawbacks,
too. For example, we can't use sed -e '$-10,$d',
since sed doesn't know $ before
the end of file, so it doesn't know where $-10
is. This is a major problem, and it limits sed(1)'s usefulness, but sed(1) still has a large number
of appliances.
Another way to get only the first 10 lines is to use the
-n option:
sed -n -e '1,10p'
If we want to delete only one line, the pattern can be
'10,10' or simple
'10'.
Commands in sed(1) programs are separated by new lines. So if we
wanted to delete the lines 1 to 4 and 6 to 9, we could use:
sed -e '1,4d 6,9d'
Another possibility is to use the
-e option more than once:
sed -e '1,4d' -e '6,9d'
That's why we used the -e
option all the time. In fact, you can omit it if you have only one command in your program. But
you should get used to the -e option,
so you won't have to add it if you want to extend your program later on.
Often, we don't know the numbers of the lines we want to delete.
A good example is a log file. Log files tend to grow until they become too large to handle. Let's
assume that you have a large log file called log
which contains thousands of lines. Now you want to delete all the lines that contain the word ``debug'':
We are still working with the large log file. Now we not only want
to delete lines with the word debug, but we only want lines that contain ``foo''. The traditional
way to handle this would be:
grep 'foo'
Note that this spawns two grep processes. The sed equivalent would
be:
sed -n -e '/debug/d' -e '/foo/p'
You might wonder why lines with debug aren't printed if they
contain foo. The answer is that the ``d'' action skips the rest of the patterns and actions, too,
it does not just inhibit the print in the end (which is inhibited here due to the
-n, anyway).
Now that your programs are getting a little more advanced,
you might want to put them in script files instead of using the command line. To tell sed(1) about
your program file, you use the -f
option:
sed -f program.sed
There is a kludge in sed(1) that allows you to set the
-n option from within your sed
program if you use ``#n'' as the first line in your program file. From now on I
will assume that you run the examples through sed -f.
You can insert text with the ``a'' and ``i'' actions. The syntax
is:
10i\ string to be inserted
The difference between ``i'' and ``a'' is that ``i'' inserts before
the current line and ``a'' appends after the current line. So ``1i'' will insert before the first
line and ``$a'' will append after the last line.
The ``l'' action is very useful when editing
files with nonprintable characters. It prints the current line visually unambiguously. For example,
long lines are broken, but the lines end with a \ to show that they were broken. Normal backslashes
in the text are escaped, too, tabs are replaced with \t
and nonprintable characters are printed as escaped three-digit octal numbers. This example is quite
useful as shell alias:
The ``q'' action branches to the end of the script and ends the script
processing after this line. So, yet another way of printing the first 10 lines would have been:
The ``s/pattern/replacement/[flags]'' action is the
most often used sed(1) action. In fact, most sed programs consist only of substitute commands, since
this is so immensely useful. The regular expression pattern is substituted by the replacement
string (which can contain several special symbols). The most basic substitution would be
sed -e 's/foo/bar/'
which would just change the string ``foo'' to ``bar''.
SunWorld December 1999 Hands-off editing with sed, Part 1.
Now SunWorld site is renamed to Unix insider and many old papers are still missing; at this point
I do not have a link to the paper, but here is mirror:
sed The
canonical reference to sed is a technical paper, sed -- a Non-interactive Text Editor, by L. E.
McMahon, reprinted in Volume 2 of the UNIX Research System Manual, tenth edition. Here is PDF version
sed
sed The
canonical reference to sed is a technical paper, sed -- a Non-interactive Text Editor,
by L. E. McMahon, reprinted in Volume 2 of the UNIX Research System Manual, tenth edition.
Here is PDF version
sed
sed1line
SED onelines compiled by Eric Pement
-- very useful (reproduced below in full from Google cache as it seems to disappeared
from the Web). The current version is 5.1
Note: [Nov 11, 2002] New Web home for the version 5. 1 file
www.student.northpark.edu
was reported to me by Daniel Biddle. The reference in Tips was changed accordingly.
FILE SPACING:
# double space a file
sed G
# triple space a file
sed 'G;G'
# undo double-spacing (assumes even-numbered lines are always blank)
sed 'n;d'
NUMBERING:
# number each line of a file (simple left alignment). Using a tab (see
# note on '\t' at end of file) instead of space will preserve margins.
sed = filename | sed 'N;s/\n/\t/'
# number each line of a file (number on left, right-aligned)
sed = filename | sed 'N; s/^/ /; s/ *\(.\{6,\}\)\n/\1 /'
# number each line of file, but only print numbers if line is not blank
sed '/./=' filename | sed '/./N; s/\n/ /'
# count lines (emulates "wc -l")
sed -n '$='
TEXT CONVERSION AND SUBSTITUTION:
# IN UNIX ENVIRONMENT: convert DOS newlines (CR/LF) to Unix format
sed 's/.$//' # assumes that all lines end with CR/LF
sed 's/^M$//' # in bash/tcsh, press Ctrl-V then Ctrl-M
sed 's/\x0D$//' # gsed 3.02.80, but top script is easier
# IN UNIX ENVIRONMENT: convert Unix newlines (LF) to DOS format
sed "s/$/`echo -e \\\r`/" # command line under ksh
sed 's/$'"/`echo \\\r`/" # command line under bash
sed "s/$/`echo \\\r`/" # command line under zsh
sed 's/$/\r/' # gsed 3.02.80
# IN DOS ENVIRONMENT: convert Unix newlines (LF) to DOS format
sed "s/$//" # method 1
sed -n p # method 2
# IN DOS ENVIRONMENT: convert DOS newlines (CR/LF) to Unix format
# Cannot be done with DOS versions of sed. Use "tr" instead.
tr -d \r <infile >outfile # GNU tr version 1.22 or higher
# delete leading whitespace (spaces, tabs) from front of each line
# aligns all text flush left
sed 's/^[ \t]*//' # see note on '\t' at end of file
# delete trailing whitespace (spaces, tabs) from end of each line
sed 's/[ \t]*$//' # see note on '\t' at end of file
# delete BOTH leading and trailing whitespace from each line
sed 's/^[ \t]*//;s/[ \t]*$//'
# insert 5 blank spaces at beginning of each line (make page offset)
sed 's/^/ /'
# align all text flush right on a 79-column width
sed -e :a -e 's/^.\{1,78\}$/ &/;ta' # set at 78 plus 1 space
# center all text in the middle of 79-column width. In method 1,
# spaces at the beginning of the line are significant, and trailing
# spaces are appended at the end of the line. In method 2, spaces at
# the beginning of the line are discarded in centering the line, and
# no trailing spaces appear at the end of lines.
sed -e :a -e 's/^.\{1,77\}$/ & /;ta' # method 1
sed -e :a -e 's/^.\{1,77\}$/ &/;ta' -e 's/\( *\)\1/\1/' # method 2
# substitute (find & replace) "foo" with "bar" on each line
sed 's/foo/bar/' # replaces only 1st instance in a line
sed 's/foo/bar/4' # replaces only 4th instance in a line
sed 's/foo/bar/g' # replaces ALL instances in a line
# substitute "foo" with "bar" ONLY for lines which contain "baz"
sed '/baz/s/foo/bar/g'
# substitute "foo" with "bar" EXCEPT for lines which contain "baz"
sed '/baz/!s/foo/bar/g'
# change "scarlet" or "ruby" or "puce" to "red"
sed 's/scarlet/red/g;s/ruby/red/g;s/puce/red/g' # most seds
gsed 's/scarlet\|ruby\|puce/red/g' # GNU sed only
# reverse order of lines (emulates "tac")
# bug/feature in HHsed v1.5 causes blank lines to be deleted
sed '1!G;h;$!d' # method 1
sed -n '1!G;h;$p' # method 2
# reverse each character on the line (emulates "rev")
sed '/\n/!G;s/\(.\)\(.*\n\)/&\2\1/;//D;s/.//'
# join pairs of lines side-by-side (like "paste")
sed '$!N;s/\n/ /'
# if a line ends with a backslash, append the next line to it
sed -e :a -e '/\\$/N; s/\\\n//; ta'
# if a line begins with an equal sign, append it to the previous line
# and replace the "=" with a single space
sed -e :a -e '$!N;s/\n=/ /;ta' -e 'P;D'
# add commas to numeric strings, changing "1234567" to "1,234,567"
gsed ':a;s/\B[0-9]\{3\}\>/,&/;ta' # GNU sed
sed -e :a -e 's/\(.*[0-9]\)\([0-9]\{3\}\)/\1,\2/;ta' # other seds
# add commas to numbers with decimal points and minus signs (GNU sed)
gsed ':a;s/\(^\|[^0-9.]\)\([0-9]\+\)\([0-9]\{3\}\)/\1\2,\3/g;ta'
# add a blank line every 5 lines (after lines 5, 10, 15, 20, etc.)
gsed '0~5G' # GNU sed only
sed 'n;n;n;n;G;' # other seds
SELECTIVE PRINTING OF CERTAIN LINES:
# print first 10 lines of file (emulates behavior of "head")
sed 10q
# print first line of file (emulates "head -1")
sed q
# print the last 10 lines of a file (emulates "tail")
sed -e :a -e '$q;N;11,$D;ba'
# print the last 2 lines of a file (emulates "tail -2")
sed '$!N;$!D'
# print the last line of a file (emulates "tail -1")
sed '$!d' # method 1
sed -n '$p' # method 2
# print only lines which match regular expression (emulates "grep")
sed -n '/regexp/p' # method 1
sed '/regexp/!d' # method 2
# print only lines which do NOT match regexp (emulates "grep -v")
sed -n '/regexp/!p' # method 1, corresponds to above
sed '/regexp/d' # method 2, simpler syntax
# print 1 line of context before and after regexp, with line number
# indicating where the regexp occurred (similar to "grep -A1 -B1")
sed -n -e '/regexp/{=;x;1!p;g;$!N;p;D;}' -e h
# grep for AAA and BBB and CCC (in any order)
sed '/AAA/!d; /BBB/!d; /CCC/!d'
# grep for AAA and BBB and CCC (in that order)
sed '/AAA.*BBB.*CCC/!d'
# grep for AAA or BBB or CCC (emulates "egrep")
sed -e '/AAA/b' -e '/BBB/b' -e '/CCC/b' -e d # most seds
gsed '/AAA\|BBB\|CCC/!d' # GNU sed only
# print paragraph if it contains AAA (blank lines separate paragraphs)
# HHsed v1.5 must insert a 'G;' after 'x;' in the next 3 scripts below
sed -e '/./{H;$!d;}' -e 'x;/AAA/!d;'
# print paragraph if it contains AAA and BBB and CCC (in any order)
sed -e '/./{H;$!d;}' -e 'x;/AAA/!d;/BBB/!d;/CCC/!d'
# print paragraph if it contains AAA or BBB or CCC
sed -e '/./{H;$!d;}' -e 'x;/AAA/b' -e '/BBB/b' -e '/CCC/b' -e d
gsed '/./{H;$!d;};x;/AAA\|BBB\|CCC/b;d' # GNU sed only
# print only lines of 65 characters or longer
sed -n '/^.\{65\}/p'
# print only lines of less than 65 characters
sed -n '/^.\{65\}/!p' # method 1, corresponds to above
sed '/^.\{65\}/d' # method 2, simpler syntax
# print section of file from regular expression to end of file
sed -n '/regexp/,$p'
# print section of file based on line numbers (lines 8-12, inclusive)
sed -n '8,12p' # method 1
sed '8,12!d' # method 2
# print line number 52
sed -n '52p' # method 1
sed '52!d' # method 2
sed '52q;d' # method 3, efficient on large files
# beginning at line 3, print every 7th line
gsed -n '3~7p' # GNU sed only
sed -n '3,${p;n;n;n;n;n;n;}' # other seds
# print section of file between two regular expressions (inclusive)
sed -n '/Iowa/,/Montana/p' # case sensitive
SELECTIVE DELETION OF CERTAIN LINES:
# print all of file EXCEPT section between 2 regular expressions
sed '/Iowa/,/Montana/d'
# delete duplicate, consecutive lines from a file (emulates "uniq").
# First line in a set of duplicate lines is kept, rest are deleted.
sed '$!N; /^\(.*\)\n\1$/!P; D'
# delete duplicate, nonconsecutive lines from a file. Beware not to
# overflow the buffer size of the hold space, or else use GNU sed.
sed -n 'G; s/\n/&&/; /^\([ -~]*\n\).*\n\1/d; s/\n//; h; P'
# delete the first 10 lines of a file
sed '1,10d'
# delete the last line of a file
sed '$d'
# delete the last 2 lines of a file
sed 'N;$!P;$!D;$d'
# delete the last 10 lines of a file
sed -e :a -e '$d;N;2,10ba' -e 'P;D' # method 1
sed -n -e :a -e '1,10!{P;N;D;};N;ba' # method 2
# delete every 8th line
gsed '0~8d' # GNU sed only
sed 'n;n;n;n;n;n;n;d;' # other seds
# delete ALL blank lines from a file (same as "grep '.' ")
sed '/^$/d' # method 1
sed '/./!d' # method 2
# delete all CONSECUTIVE blank lines from file except the first; also
# deletes all blank lines from top and end of file (emulates "cat -s")
sed '/./,/^$/!d' # method 1, allows 0 blanks at top, 1 at EOF
sed '/^$/N;/\n$/D' # method 2, allows 1 blank at top, 0 at EOF
# delete all CONSECUTIVE blank lines from file except the first 2:
sed '/^$/N;/\n$/N;//D'
# delete all leading blank lines at top of file
sed '/./,$!d'
# delete all trailing blank lines at end of file
sed -e :a -e '/^\n*$/N;/\n$/ba'
# delete the last line of each paragraph
sed -n '/^$/{p;h;};/./{x;/./p;}'
SPECIAL APPLICATIONS:
# remove nroff overstrikes (char, backspace) from man pages. The 'echo'
# command may need an -e switch if you use Unix System V or bash shell.
sed "s/.`echo \\\b`//g" # double quotes required for Unix environment
sed 's/.^H//g' # in bash/tcsh, press Ctrl-V and then Ctrl-H
sed 's/.\x08//g' # hex expression for sed v1.5
# get Usenet/e-mail message header
sed '/^$/q' # deletes everything after first blank line
# get Usenet/e-mail message body
sed '1,/^$/d' # deletes everything up to first blank line
# get Subject header, but remove initial "Subject: " portion
sed '/^Subject: */!d; s///;q'
# get return address header
sed '/^Reply-To:/q; /^From:/h; /./d;g;q'
# parse out the address proper. Pulls out the e-mail address by itself
# from the 1-line return address header (see preceding script)
sed 's/ *(.*)//; s/>.*//; s/.*[:<] *//'
# add a leading angle bracket and space to each line (quote a message)
sed 's/^/> /'
# delete leading angle bracket & space from each line (unquote a message)
sed 's/^> //'
# remove most HTML tags (accommodates multiple-line tags)
sed -e :a -e 's/<[^>]*>//g;/</N;//ba'
# extract multi-part uuencoded binaries, removing extraneous header
# info, so that only the uuencoded portion remains. Files passed to
# sed must be passed in the proper order. Version 1 can be entered
# from the command line; version 2 can be made into an executable
# Unix shell script. (Modified from a script by Rahul Dhesi.)
sed '/^end/,/^begin/d' file1 file2 ... fileX | uudecode # vers. 1
sed '/^end/,/^begin/d' "$@" | uudecode # vers. 2
# zip up each .TXT file individually, deleting the source file and
# setting the name of each .ZIP file to the basename of the .TXT file
# (under DOS: the "dir /b" switch returns bare filenames in all caps).
echo @echo off >zipup.bat
dir /b *.txt | sed "s/^\(.*\)\.TXT/pkzip -mo \1 \1.TXT/" >>zipup.bat
TYPICAL USE: Sed takes one or more editing commands and applies all of
them, in sequence, to each line of input. After all the commands have
been applied to the first input line, that line is output and a second
input line is taken for processing, and the cycle repeats. The
preceding examples assume that input comes from the standard input
device (i.e, the console, normally this will be piped input). One or
more filenames can be appended to the command line if the input does
not come from stdin. Output is sent to stdout (the screen). Thus:
cat filename | sed '10q' # uses piped input
sed '10q' filename # same effect, avoids a useless "cat"
sed '10q' filename > newfile # redirects output to disk
For additional syntax instructions, including the way to apply editing
commands from a disk file instead of the command line, consult "sed &
awk, 2nd Edition," by Dale Dougherty and Arnold Robbins (O'Reilly,
1997; http://www.ora.com), "UNIX Text Processing," by Dale Dougherty
and Tim O'Reilly (Hayden Books, 1987) or the tutorials by Mike Arst
distributed in U-SEDIT2.ZIP (many sites). To fully exploit the power
of sed, one must understand "regular expressions." For this, see
"Mastering Regular Expressions" by Jeffrey Friedl (O'Reilly, 1997).
The manual ("man") pages on Unix systems may be helpful (try "man
sed", "man regexp", or the subsection on regular expressions in "man
ed"), but man pages are notoriously difficult. They are not written to
teach sed use or regexps to first-time users, but as a reference text
for those already acquainted with these tools.
QUOTING SYNTAX: The preceding examples use single quotes ('...')
instead of double quotes ("...") to enclose editing commands, since
sed is typically used on a Unix platform. Single quotes prevent the
Unix shell from intrepreting the dollar sign ($) and backquotes
(`...`), which are expanded by the shell if they are enclosed in
double quotes. Users of the "csh" shell and derivatives will also need
to quote the exclamation mark (!) with the backslash (i.e., \!) to
properly run the examples listed above, even within single quotes.
Versions of sed written for DOS invariably require double quotes
("...") instead of single quotes to enclose editing commands.
USE OF '\t' IN SED SCRIPTS: For clarity in documentation, we have used
the expression '\t' to indicate a tab character (0x09) in the scripts.
However, most versions of sed do not recognize the '\t' abbreviation,
so when typing these scripts from the command line, you should press
the TAB key instead. '\t' is supported as a regular expression
metacharacter in awk, perl, and HHsed, sedmod, and GNU sed v3.02.80.
VERSIONS OF SED: Versions of sed do differ, and some slight syntax
variation is to be expected. In particular, most do not support the
use of labels (:name) or branch instructions (b,t) within editing
commands, except at the end of those commands. We have used the syntax
which will be portable to most users of sed, even though the popular
GNU versions of sed allow a more succinct syntax. When the reader sees
a fairly long command such as this:
sed -e '/AAA/b' -e '/BBB/b' -e '/CCC/b' -e d
it is heartening to know that GNU sed will let you reduce it to:
sed '/AAA/b;/BBB/b;/CCC/b;d' # or even
sed '/AAA\|BBB\|CCC/b;d'
In addition, remember that while many versions of sed accept a command
like "/one/ s/RE1/RE2/", some do NOT allow "/one/! s/RE1/RE2/", which
contains space before the 's'. Omit the space when typing the command.
OPTIMIZING FOR SPEED: If execution speed needs to be increased (due to
large input files or slow processors or hard disks), substitution will
be executed more quickly if the "find" expression is specified before
giving the "s/.../.../" instruction. Thus:
sed 's/foo/bar/g' filename # standard replace command
sed '/foo/ s/foo/bar/g' filename # executes more quickly
sed '/foo/ s//bar/g' filename # shorthand sed syntax
On line selection or deletion in which you only need to output lines
from the first part of the file, a "quit" command (q) in the script
will drastically reduce processing time for large files. Thus:
sed -n '45,50p' filename # print line nos. 45-50 of a file
sed -n '51q;45,50p' filename # same, but executes much faster
If you have any additional scripts to contribute or if you find errors
in this document, please send e-mail to the compiler. Indicate the
version of sed you used, the operating system it was compiled for, and
the nature of the problem. Various scripts in this file were written
or contributed by:
Al Aab <[email protected]> # "seders" list moderator
Edgar Allen <[email protected]> # various
Yiorgos Adamopoulos <[email protected]>
Dale Dougherty <[email protected]> # author of "sed & awk"
Carlos Duarte <[email protected]> # author of "do it with sed"
Eric Pement <[email protected]> # author of this document
Ken Pizzini <[email protected]> # author of GNU sed v3.02
S.G.Ravenhall <[email protected]> # great de-html script
Greg Ubben <[email protected]> # many contributions & much help
#! /bin/sed -f
# remove all trailing /s
s/\/*$//
# add ./ if there are no path, only filename
/\//!s/^/.\//
# save path+filename
h
# remove path
s/.*\///
# do conversion only on filename
y/ABCDEFGHIJKLMNOPQRSTUVWXYZ/abcdefghijklmnopqrstuvwxyz/
# swap, now line contains original path+file, hold space contains conv filename
x
# add converted file name to line, which now contains something like
# path/file-name\nconverted-file-name
G
# check if converted file name is equal to original file name, if it is, do
# not print nothing
/^.*\/\(.*\)\n\1/b
# now, transform path/fromfile\ntofile, into mv path/fromfile path/tofile
# and print it
s/^\(.*\/\)\(.*\)\n\(.*\)$/mv \1\2 \1\3/p
The Last but not LeastTechnology is dominated by
two types of people: those who understand what they do not manage and those who manage what they do not understand ~Archibald Putt.
Ph.D
FAIR USE NOTICEThis site contains
copyrighted material the use of which has not always been specifically
authorized by the copyright owner. We are making such material available
to advance understanding of computer science, IT technology, economic, scientific, and social
issues. We believe this constitutes a 'fair use' of any such
copyrighted material as provided by section 107 of the US Copyright Law according to which
such material can be distributed without profit exclusively for research and educational purposes.
This is a Spartan WHYFF (We Help You For Free)
site written by people for whom English is not a native language. Grammar and spelling errors should
be expected. The site contain some broken links as it develops like a living tree...
You can use PayPal to to buy a cup of coffee for authors
of this site
Disclaimer:
The statements, views and opinions presented on this web page are those of the author (or
referenced source) and are
not endorsed by, nor do they necessarily reflect, the opinions of the Softpanorama society.We do not warrant the correctness
of the information provided or its fitness for any purpose. The site uses AdSense so you need to be aware of Google privacy policy. You you do not want to be
tracked by Google please disable Javascript for this site. This site is perfectly usable without
Javascript.
